Processing ライブラリのインストール先（v149以降）

現在Processingの最新バージョンは152になっており、いくつかの内容変更があります。特にProcessing 149以降では、ダウンロードしたライブラリをインストールする際（例えば、サウンドライブラリである「minim」など）、スケッチフォルダ内に「libraries」というフォルダを作成し、そのなかにダウンロードしたライブラリを入れるようになりました。
例えば、「minim」の場合なら、ダウンロードした「minim」というフォルダを、MacOSの場合、/Users/username/Documents/Processing/librariesの中に入れるということになります（「username」部分は各ユーザの名前のディレクトリです）。Macintosh HD>ユーザ>各ユーザ名>書類>Processing>libraries>minimという感じです。

追記：
バージョン155以降では、「libraries」フォルダがない場合には自動的に作成されるようになったようです。

Arduino-Processing シリアル通信６

【変更】以下はArduino1.0まで対応したプログラム内容です。

特にシリアル通信においては、Arduino2.0使用の際、バイト送信する場合、

Serial.print(value,BYTE);

のかわりに、

Serial.write(value);

を使用してください。

これまでのシリアル通信では、ProcessingとArduinoの一対一の通信を行ってきましたが、今回はProcessingで二つのシリアルポートを使い、二つのArduinoとシリアル通信を行う実験をしてみます。それぞれのArduino基盤には可変抵抗器をとりつけて入力値をProcessingへ別々に送信することにします。Processingの画面では、二つの入力信号を個別に読み取ってそれぞれの状態を描画することにします。

具体的なサンプルとして、「Pong」（下画像）のように二つのコントローラによって対戦するプログラムにします。それぞれのArduino基盤がコントローラとしてコンピュータに接続され、画面上でそれぞれのラケットを動かすことになります（得点のプログラムは含まれていません）。


（上画像：Processingの画面「Pong」）

Arduino基盤と可変抵抗器の接続は以下のようになります（二つ必要です）。



Arduinoのプログラム：

void setup(){
  Serial.begin(9600);
}

void loop(){
  //可変抵抗器の読み取り
  int val=analogRead(0);
  //シリアル通信処理
  if(Serial.available()>0){//合図用データが一つ来たら
    //合図用データを読み込んでバッファを空にする
    Serial.read();
    //読取値を４で割り、バイトで送信
    Serial.print(val/4,BYTE);
  }
}

Arduino側のプログラムでは、可変抵抗器からの読取り値を４で割ってスケールダウンした値（0~255）をシリアル通信でProcessing側へ送信しています（同期通信させるために合図用データを用いるシリアル通信の方法については「Arduino-Processing　シリアル通信２」を参照して下さい）。二つのArduino基盤とも同じ内容になります。

Processingのプログラム：

//シリアル通信ライブラリを取り込む
import processing.serial.*;
//二つのポートのインスタンス
Serial portA;
Serial portB;
//二つの読取値の変数
int valA=100,valB=100;
//ボ−ル座標用変数
int x=100,y=100;
//ボールの動きの向きの変数（1:正の向き、-1:負の向き）
int dirX=1,dirY=1;

void setup(){
  //画面サイズ設定
  size(300,256);
  //二つのシリアルポート設定
  portA = new Serial(this, "/dev/tty.usbserial-A50019vD", 9600);
  portB = new Serial(this, "/dev/tty.usbserial-A40014iU", 9600);
  //図形外形線なし
  noStroke();
  //塗り色（白）
  fill(255);
  //矩形描画位置を中央に設定
  rectMode(CENTER);
}

void draw(){
  //背景（黒）
  background(0);
  //左ラケット描画（valAをY座標に代入）
  rect(20,valA,10,30);
  //右ラケット描画（valBをY座標に代入）
  rect(280,valB,10,30);
  //ボール描画
  rect(x,y,10,10);

  //ボールX座標の動き
  x+=dirX;//X軸方向に+1または-1ずつ進める

  //ラケットAに当たった時のはね返り
  if(x==30 && y>valA-15 && y<valA+15){
    dirX*=-1;//向きを反転する
  }
  //ラケットBに当たった時のはね返り
  if(x==270 && y>valB-15 && y<valB+15){
    dirX*=-1;//向きを反転する
  }
  //画面左端からはみ出た場合
  if(x<0){
    x=270;//右側に戻る
  }
  //画面右端からはみ出た場合
  if(x>width){
    x=30;//画面左側に戻る
  }

  //ボールY座標の動き
  y+=dirY;//Y軸方向に+1または-1ずつ進める

  //画面上下位置でのはね返り
  if(y<5 || y>251){
    dirY*=-1;//向きを反転する
  }  
}

//キーを押した場合
void keyPressed(){
  //「s」キーでシリアル通信開始
  if(key=='s'){
    //二つのポートへ開始用データ送信
    portA.write(65);
    portB.write(65);
  }
}

//シリアル通信処理
void serialEvent(Serial p){
  //portAの場合
  if(p==portA){
    if(p.available()>0){
      //値を読み込みvalAに代入
      valA=p.read();
      //合図用データ送信
      portA.write(65);
    }
  }
  //portBの場合
  if(p==portB){
    if(p.available()>0){
      //値を読み込みvalBに代入
      valB=p.read();
      //合図用データ送信
      portB.write(65);
    }
  }
}

Processing側のプログラムでは、二つのシリアルポートを用意し、それぞれportA、portB（名前は任意）にしておきます。serialEvent(Serial p){...}の括弧内のpは、ポート名に対応しています（今回の場合は、pはportAまたはportBに対応します）。serialEvent()は、Processingがデータを受信した際に作動するので、if()文を使ってどちらのポートなのかを条件分けして判別し、ポートに応じてそれぞれの読込み値を変数に代入します。同期通信させるために、Arduinoから送信されたデータをp.available()で確認しデータを読み込んだ後に、合図用データ（0~255の数値あるいは'A'や'a'などの一つの文字／１バイト分のデータ）を送信しています。
Processingのプログラムを開始したら、「s」キーを押すことでシリアル通信を開始することにしました（プログラム開始から数秒経った後に「s」キーを押さないと、シリアル通信が開始されないことがあります）。

関連：
「Arduino-Processing　シリアル通信１」（一つの値を送る／非同期通信）
「Arduino-Processing　シリアル通信２」（複数の値をバイトで送る／同期通信）
「Arduino-Processing　シリアル通信３」（大きな値を複数送る）
「Processing-Arduino　シリアル通信４」（ProcessingからArduinoを制御する）
「Arduino-Processing　シリアル通信５」（複数の値を文字列で送信する）

Arduino+Xbee Shield/Processing+XBee Explorer USB

Arduinoにはワイヤレス通信するためのXbee Shieldがあります。今回はArduinoのXbee Shieldのサイトを参考に簡単な通信実験から始めたいと思います。Xbee Shiledを装着したArduino基板が２個必要になります。


（Xbee Shiledを装着したArduino基板）

注意しなければいけないことは、Arduino基板にXbee Shiledを装着したままプログラムをアップロードする際、Xbee Shiled上にある二つのジャンパピン（二つの間には「XBEE/USB」と表示されています）を「USB」側に差し替えなければいけないことです（３本のピンのうち、USB側のピンと中央のピンの２本のピンに差し込まれている状態になります）。
尚、アップロード後は「XBEE」側のピンと中央のピンの２本のピンに差し込まれている状態に戻してください。


「二つのArduino間での通信」：
以下では、Xbee Shieldのサイトに従って、LEDの点滅実験を行います。一方のXbee Shiledを装着したArduino基板から、一秒おきに'H'か'L'の文字を送信し、受信したもう一方のXbee Shiledを装着したArduino基板の13番ピンに接続されたLEDが点滅する内容です。基本的には、通常のシリアル通信のプログラムと同じような内容になります。

送信側Arduinoのプログラム：

void setup(){
  //シリアル通信開始
  Serial.begin(9600);
}

void loop(){
  Serial.print('H');//「H」を送信（点灯）
  delay(1000);      //１秒待つ
  Serial.print('L');//「L」を送信（消灯）
  delay(1000);      //１秒待つ
}

送信側は一方的に'H'と'L'を１秒間隔で送信するだけです。受信側は、送信側からのデータが届いたら読み込みをし、データが「H」であれば13番ピンをHIGHで出力し、そうでなければLOWで出力するプログラムになります。

受信側Arduinoのプログラム：

int val;//受信データ用の変数を用意

void setup(){
  //シリアル通信開始
  Serial.begin(9600);
  //13ピンをデジタル出力に設定
  pinMode(13,OUTPUT);
}

void loop(){
  if(Serial.available()>0){ //データが来たら
    val=Serial.read();    //データを読み込み、valへ代入
  }
  if(val=='H'){           //valが「H」の場合
    digitalWrite(13,HIGH);//点灯
  }else{                  //valが「L」の場合
    digitalWrite(13,LOW); //消灯
  }
}

乾電池などの外部電源でArduinoを作動させれば、それぞれスタンドアロンで通信し合います。Decimilaなどの旧型のArduino基板の場合、外部電源を使うにはArduino基板についている「USB/EXT」のジャンパピンを「EXT」側に差し替える必要があります（プログラムをアップロードする際には、パソコンとUSB接続し、ジャンパピンも「USB」側に差し替えて下さい）。



「コンピュータに接続したXbeeと通信」:
コンピュータにXbeeを接続し、Arduinoとワイヤレス通信するには以下のようになります。
Sparkfunで販売されている「XBee Explorer USB」を使うと簡単にコンピュータとUSB接続でき、Processingからワイヤレスにシリアル通信が可能になります。


（左：「XBee Explorer USB」、右：Xbeeを装着した状態）

以下では、先ほどの受信用のXbee Shieldを装着したArduino基板に対して、Xbeeモジュールを装着した「XBee Explorer USB」を通して、Processingからワイヤレスでシリアル通信してみます。
まず、「XBee Explorer USB」のシリアルポートを調べてみます。

import processing.serial.*;
println(Serial.list());

「XBee Explorer USB」をコンピュータに接続し、上記の二行のプログラムをランさせれば、「XBee Explorer USB」のシリアルポートが出力されるはずです。


「Processingのプログラム」：
受信側となるArduinoのプログラムは先ほどと同じものを使い、送信側となるProcessingだけのプログラムを以下に書きます。マウスボタンを押したら点灯、放したら消灯する内容とします。

//シリアル通信ライブラリを取り入れる
import processing.serial.*;
//ポートのインスタンス
Serial port;

void setup(){
  //「XBee Explorer USB」のシリアルポート設定
  port=new Serial(this,"/dev/tty.usbserial-A8003VXd",9600);
}
void draw(){
  //特になし  
}

void mousePressed(){//マウスボタンを押したら
  port.write('H');  //「H」を送信（点灯）
}

void mouseReleased(){//マウスボタンを放したら
  port.write('L');   //「L」を送信（消灯）
}

プログラムの内容はこれまでのシリアル通信と同じなので、ポートの設定、接続やジャンパピンの差し替えなどを間違わなければ特に問題はないと思います。



「Xbeeモジュールの設定／ATコマンド」：
XbeeにATコマンドを送ることで、Xbeeモジュール自体の設定を確認したり変更することができます。ATコマンドをXbeeモジュールに送信するには、MacOSXなら「ZTerm」など、Windowsなら「ハイパーターミナル」や「Tera Term」などのターミナルアプリケーションで入力すると便利です（「ZTerm」と「ハイパーターミナル」の設定や使い方については、「Arduino-Processing　BlueTooth通信+曲げセンサ」にも、説明があります）。

コンフィグレーションモードに入るには、

+++

プラスを３回入力し待機します（リターンキーは押さない）。そうすれば、

OK

という返事が返ってきます（ATコマンドモードでは、「+++」を押したあと１秒後に「OK」が返答され、さらに１０秒以内に次のコマンドを送信しなければコマンドモードが自動的に終了してしまうので、返答がない場合は再度「+++」を押す必要があります）。さらに続けて、

ATID（リターンキーを押して送信）

と押せば、デフォルトの状態であれば、

3332

という数値が返ってきます。「3332」という数値は、そのモジュールのネットワークIDであり、このネットワークIDを変更すれば同じネットワークIDを共有しているXbeeモジュール間だけでの通信が可能になります（ひとつのモジュールだけでなく、相手になるモジュールも変える必要があります）。
設定されている通信速度を確認するには、

ATBD（リターンキーを押して送信）

と押せば、デフォルトであれば、

3

という数値が返ってきます。通信速度はそれぞれ

0:1200 bps
1:2400 bps
2:4800 bps
3:9600 bps
4:19200 bps
5:38400 bps
6:57600 bps
7:115200 bps

なので、デフォルトの「3」は9600 bpsということになります。

ATBD4（リターンキーを押して送信）

と打てば（「ATBD」の後に「4」を付け加える）、通信速度は「4」（19200）に変更されます（「OK」という返答がきます）。再度、

ATBD（リターンキーを押して送信）

と打てば、変更した内容を確認できます（この場合「4」という数値が返ってきます）。ただし、この場合電源が切れると設定内容は消えてしまいます。電源を切っても設定内容が戻らないようにするには、

ATWR（リターンキーを押して送信）

を変更後すぐに送信します（「OK」という返答がきます）。あるいは、

ATBD4,WR（リターンキーを押して送信）

という感じで、コマンドを複数合成して送信することもできます（「OK OK」という二つ分の返答がきます）。デフォルトの状態に戻すには、

ATRE（リターンキーを押して送信）

になるのですが、「WR」を付け加えていないので再度電源を入れたときには前回の状態に戻ってしまいます。

ATRE,WR（リターンキーを押して送信）

とすれば、電源を入れ直してもデフォルト状態は保持されます。
尚、コマンドモードから出るには、

ATCN（リターンキーを押して送信）

になります。
デフォルトでは、

ID:3332（ネットワークID）
CH:0x0C（チャンネル）
MY:0（そのモジュールのアドレス）
SH: （シリアルナンバー上位32ビット／モジュールごとに異なる）
SL: （シリアルナンバー下位32ビット／モジュールごとに異なる）
DH:0（送信先アドレス上位32ビット）
DL:0（送信先アドレス下位32ビット）
BD:3（通信速度：9600　bps）

に設定されており、ネットワーク、チャンネル、モジュールのアドレス、送信先アドレスがそれぞれ同じであるため、どのモジュール間でも通信可能です。逆に、ネットワークIDを変更してしまえば、他のモジュール群から干渉を受けずに通信し合うことも可能になります。あるいは、二つのモジュール間で送信先を互いに設定してしまえば、そのアドレスのモジュールだけとの通信が可能になります。そのためには、IDとCHは共有しておき、それぞれのモジュールアドレスを個別に設定しておきます。

ATMY1111,WR（リターンキーを押して送信）
OK OK（Xbeeからの返信）

とすれば、このモジュールの「MY」は「1111」に設定されたことになります（「WR」を付け加えたので、電源を落としても変更内容は記憶されます）。さらに送信先のアドレスを「2222」に設定するには、「DL」を「2222」に「DH」を「0」にします。

ATDL2222,DH0,WR（リターンキーを押して送信）
OK OK OK（Xbeeからの返信）

もう一方のほうも設定する必要があるので、「MY」を「2222」、「DL」を「1111」、「DH」を「0」にします。

ATMY2222,DL1111,DH0,WR（リターンキーを押して送信）
OK OK OK OK（Xbeeからの返信）

とします。こうすることで、「1111」のモジュールと「2222」のモジュールが互いに送信先を特定して通信し合うことができます。

Arduino Xbee Shieldサイトの説明によれば、「DH」を「0」、「DL」を「FFFF」に設定すれば、そのモジュールからの通信は、その他のすべてのモジュールによって受信可能になります。
また、送信先アドレス（上位ビットDHと下位ビットDL）が「FFFF」より大きい値（つまり「DH」が「0」以外の数値に設定したとき）、その「DH」と「DL」が相手モジュールの「SH」と「SL」に等しければ、相手モジュールのみに受信させることが可能になります。ただし、この場合も、ネットワークIDとチャンネルは同じでなければなりません。


「Ztermの設定」：
以下は、MacOSXで「ZTerm」を使ったときの画面です。


ATコマンドを打つ画面。



メニューバー>Dial>Directory...をクリックすれば、上画面が現れます。「New」を押せば、新たな接続先を追加する画面（下画像）がでてきます。



「Service Name:」の欄に適当な名前を入れます。「Local Echo」にはチェックをいれておきます。チェックを外すと、自分の打った文字は画面に現れないので、チェックを入れておいた方がいいでしょう。Xbeeがデフォルト状態であれば、その他の項目は上画面のようになります。メニューバー>Setting>Connection...をクリックすることで、再度この画面が現れます。



メニューバー>Setting>Terminal...をクリックすれば、上画面が現れます。ここでは「Auto Line Feed」にチェックをいれておきます。チェックを外すと、ATコマンドが改行されなくなるので、チェックをいれておいたほうがいいでしょう。恐らく、MacOSXの改行コードは、「CR（キャリッジリターン：行頭に戻る）」だけなので、「LF（ラインフィード：次の行に移る）」も付け加えないと改行されなくなるからでしょう。

Zigbee開発ハンドブック (実践入門ネットワーク)

posted with amazlet at 09.04.01

鄭 立
リックテレコム
売り上げランキング: 9866

Amazon.co.jp で詳細を見る

DESIGNING ZIGBEE NETWORKS AND TRANSCEIVERS: The Complete Guide for Rf/Wireless Engineers

posted with amazlet at 09.04.01

Shanin Farahani
Newnes
売り上げランキング: 21994

Amazon.co.jp で詳細を見る

次回授業（10/18）：FURNI02

次回（10/18）の授業では、「身体と装置」に関するスライドショーを行います。その後、引き続き連続する姿勢／行為をもとに応用的な実験をします。
・パソコン、Arduino、入出力装置等を各自持参して来て下さい。

Antique Furniture and Decorative Accessories: A Pictorial Archive With 3500 Illustrations (Dover Pictorial Archive Series)

posted with amazlet at 09.03.31

Thomas Arthur Strange
Dover Pubns
売り上げランキング: 42510

Amazon.co.jp で詳細を見る

Processing FileChooser２

以前「Processing　FileChooser/ファイル選択画面の表示」でJava Swingを用いましたが、Processing 146以降からselectInput()によって、ファイル選択画面を通して任意の場所にあるファイルを読み込むことが簡単にできるようになりました。
以下は、「f」キーを押すとselectInput()で、ファイル選択画面を表示し、コンピュータの任意の場所にある画像を表示するサンプルです。表示された画像は、ドラッグすることで位置を変えられるようにしてあります。

//画像用インスタンス用意
PImage img;

//現在選択中のファイルパスの変数
String currentPath=null;
//画像配置座標の変数
int x,y;
//画像配置座標とクリック座標の差分の変数
int dx,dy;

void setup(){
  //画面サイズ設定
  size(600,400);
}

void draw(){
  //背景描画（黒）
  background(0);
  //現在選択中のファイルパスが空ではないとき
  if(currentPath!=null){
    //画像描画
    image(img,x,y);
  }
}

//クリックしたら
void mousePressed(){
  //画像配置座標とクリック座標の差分を求めておく
  dx=x-mouseX;
  dy=y-mouseY;
}

//ドラッグ中
void mouseDragged(){
  //マウス座標に差分座標を加えた値を画像配置座標とする
  x=mouseX+dx;
  y=mouseY+dy;
}

//キーを押した場合
void keyPressed(){
  //「f」キーなら
  if(key=='f'){
    //ファイル選択画面を表示し選択したファイルパス取得
    String loadPath = selectInput();
    //ファイルパスが空の場合
    if (loadPath == null) {
      //「ファイルが選ばれてない」メッセージを出力
      println("No file was selected...");
      //ファイルパスを前回のファイルパスにする
      loadPath=currentPath;
    } 
    else {//ファイルパスが選択された場合
      //ファイルパスのドット以降の文字列を取得（拡張子名を取得）
      String ext = loadPath.substring(loadPath.indexOf('.') + 1);
      //拡張子が「jpg」または「png」なら
      if(ext.equals("jpg") || ext.equals("png")){
        //選択ファイルパスの画像を取り込み
        img = loadImage(loadPath);
        //現在選択中のファイルパスを更新
        currentPath=loadPath;
        //現在選択中のファイルパスを出力
        println(currentPath);
      }else{//拡張子が「jpg」または「png」ではないとき
        //「画像ファイルではない」と出力
        println("Not image file.");
      }      
    }
  }
}

ファイル選択画面上で選択したファイルのパスを取得したら、substring()によってパスの文字列末尾に含まれる拡張子を調べます。その際、indexOf()を使うことで、パスの文字列に含まれる「.」を手掛かりに、パスの文字列末尾の拡張子を抜き出します（indexOf()は、括弧内に入れた文字が文字列中の何番目にあるかを教えてくれます）。
今回は、拡張子が「jpg」か「png」であれば、loadImage()で画像を取り込み、次回のためにファイルパスを記憶させておきます。それ以外の拡張子の場合は、"Not image file."だけを出力します。

selectInput()以外に、フォルダを選択するためのselectFolder()や、保存先を指定するselectOutput()も加えられています。

----------------------------------
以下は頂いたコメントに対するサンプルです。

import java.awt.*;

void setup() {
  size(200,200);
}

void draw(){  
}

void fileSelected(File selection) {
  if (selection == null) {
    println("Window was closed or the user hit cancel.");
  } else {
    println("User selected " + selection.getAbsolutePath());
  }
}

void mousePressed(){
  FileDialog fd = new FileDialog(new Frame(),"Choose a file");
  fd.setDirectory("/Users/username/Desktop");//ここのディレクトリを任意に変えてください。
  fd.setVisible(true);
  if(fd.getFile()==null){
    println("Canceled");
  }else{
    println("FILE NAME:"+fd.getFile());
    println("DIRECTORY:"+fd.getDirectory());
  }
}