今回は秋月電子で購入した
デジタルカラーセンサS9706の実験をします。S9706は、RGB３色の同時測光が可能であり、９×９素子（高感度）と３×３素子（低感度）の感度設定が２段階あり、感度設定用の端子（Range端子）をHIGHまたはLOWで切り替えて設定できます。検出結果は12ビットの値でシリアル出力されます。S9706は表面実装用の小さな部品（1.27mmピッチ）なので、
DIP変換基板などにハンダ付けして使用したほうが実験しやすくなります。
S9706には、
・Range端子（感度設定）
・Gate端子（測光時間の設定）
・CK端子（クロックパルス）
・Dout端子（出力）
・Vdd端子（5V電源）
・Gnd端子（グランド）
の６端子あります。
それぞれを以下のように接続します。尚、測光時間を調節できるように可変抵抗器も接続することにします。
データシートの動作手順によれば、以下のように説明されています。
（１）Gate端子とCK端子をLowにします。
（２）Range端子で、所望の感度を選択します（今回は、可変抵抗器で調節可能にしておきます）。
（３）Gate端子をLow→Highにして光量の積算を開始します。
（４）所望の積算時間の後にGate端子をHigh→Lowにして光量の積算を終了します。
（５）測定データは、CK端子に36のCKパルスを入れることで、Dout端子から出力されます。
Dout端子からの12ビットのシリアル出力を読み込むためには、CK端子へ12回のパルスを３回送る必要があります。最初の12パルスによって赤、次の12パルスによって緑、そして最後の12パルスによって青が出力されます。この部分の手続きは、shiftIn()というファンクション（名前は任意）を用意することにします。
付属のデータシートのタイミングチャートに従ってプログラムしていくことにします。
最終的に得られたRGB三色の値（12ビット:0~4095）をシリアル通信でProcessingへ送信し、Processingの画面上で色表示することにします。
「Arduinoのプログラム」： [プログラムを表示]
#define RANGE 8 // 8番ピンをRange端子に設定
#define GATE 9 // 9番ピンをGate端子に設定
#define CK 10 //10番ピンをCK端子に設定
#define DOUT 11 //11番ピンをDout端子に設定
int red,green,blue;//RGB三色の変数を用意
void setup(){
//Range,Gate,CK端子をデジタル出力に設定
pinMode(RANGE,OUTPUT);
pinMode(GATE,OUTPUT);
pinMode(CK,OUTPUT);
//Dout端子をデジタル入力に設定
pinMode(DOUT,INPUT);
//シリアル通信設定
Serial.begin(9600);
}
void loop(){
//測光時間用の可変抵抗器の読み込み（アナログ入力:０番ピン）
int val=analogRead(0);
//Gate,CK端子をLowに設定
digitalWrite(GATE,LOW);
digitalWrite(CK,LOW);
delayMicroseconds(2000);//2000マイクロ秒待機
//感度設定（HIGH:高感度に設定）
digitalWrite(RANGE,HIGH);
//測光開始（光量の積算を開始）
digitalWrite(GATE,HIGH);
//測光時間（valを代入し可変的に設定）
delay(val+1);
//測光終了（光量の積算を終了）
digitalWrite(GATE,LOW);
delayMicroseconds(4);//4マイクロ秒待機
red=shiftIn();//赤の処理
green=shiftIn();//緑の処理
blue=shiftIn();//青の処理
//Gate端子をHighに戻す
digitalWrite(GATE,HIGH);
//シリアル通信でProcessingへ三色の値を文字列で送信
if(Serial.available()>0){
Serial.print(red,DEC);
Serial.print(",");
Serial.print(green,DEC);
Serial.print(",");
Serial.println(blue,DEC);
Serial.read();
}
}
//12ビット分のパルス送信と読み込み処理
int shiftIn(){
int result=0;//検出結果用の変数を用意（0：初期化）
for(int i=0;i<12;i++){//12ビット分の繰り返し処理
digitalWrite(CK,HIGH);//1ビット分のクロックパルス出力（HIGH）
delayMicroseconds(1);//1マイクロ秒待機
if(digitalRead(DOUT)==HIGH){//Dout端子からの出力がHighの場合
result+=(1<<i);//12ビットのi桁目に1を代入（i桁分だけ左にシフト）
}
digitalWrite(CK,LOW);//1ビット分のクロックパルス出力（LOW）
delayMicroseconds(1);//1マイクロ秒待機
}
delayMicroseconds(3);//3マイクロ秒待機
return result;//結果を出力
}
アナログ入力に接続された可変抵抗器で、測光時間を1ミリ秒から1024ミリ秒まで可変的に設定可能になります。測光時間が短ければ全体的に暗い色として認識されるので適宜調節してください（白色LEDを取り付けて反射光を使って読み取らせることもできると思います）。
12ビットの値を読み込む処理をするint shiftIn(){...}では、一色につき12回CK端子へパルス（HIGH:1μsec+LOW:1μsec）を送ります。12回分のパルスをfor文で繰り返し処理させています。for(){...}の中では、digitalWrite(CK,HIGH)で1回HIGHを送ったあと1マイクロ秒待機すると、Dout端子から1ビット分の出力があるので、digitalRead(DOUT)でHIGHかLOWかを読み込みます。そしてdigitalWrite(CK,LOW)によって、CK端子をLOWに戻しておきます。
読み込み値を、
000000000000~111111111111（十進数の0~4095）
までの二進数で処理するため、digitalRead(DOUT)がHIGHの場合は12ビット中のその桁が1になります。S9706では、右の桁から出力されます。つまり、for(){...}では、最初に処理される桁は右側の一桁であり、最後に処理される桁は左側の一桁（12桁目）になります。
Processingの方では４つの矩形を用意し、RGBの三色それぞれの色面とRGBを合成した色面として表示します。Arduinoとのシリアル通信は文字列で行います（複数の文字列のシリアル通信は「
Arduino-Processing シリアル通信５」を参照してください）。Processing側でクリックしたらシリアル通信を開始することにします。
Processing上の画面：左から赤、緑、青、３色合成
「Processingのプログラム」： [プログラムを表示]
//シリアルライブラリを取り込む
import processing.serial.*;
//シリアル通信用変数portを用意
Serial port;
//読み込み値（三色）の変数を用意
int r,g,b;
void setup(){
//画面サイズ設定
size(400,200);
//ポート設定
port = new Serial(this,"/dev/tty.usbserial-A6006kvP",9600);
//「10」（ラインフィード）までを読み込む設定にする
port.bufferUntil(10);
//外形線なし
noStroke();
}
void draw(){
//背景色（黒）
background(0);
fill(r,0,0);//値を塗色の赤に代入
rect(0,0,100,100);//赤の矩形
fill(0,g,0);//値を塗色の緑に代入
rect(100,0,100,100);//緑の矩形
fill(0,0,b);//値を塗色の青に代入
rect(200,0,100,100);//青の矩形
fill(r,g,b);//三つの値を塗色のRGBに代入
rect(300,0,100,100);//RGB合成した矩形
}
//シリアル通信
void serialEvent(Serial p){
//文字列の変数stringDataを用意し、
//「10」(ラインフィード)が来るまで読み込む
String stringData=port.readStringUntil(10);
//文字列データが空ではないとき
if(stringData!=null){
//文字列データに含まれる改行記号を取り除く
stringData=trim(stringData);
//整数型の配列data[]を用意し、
//コンマ記号をもとに文字列データを区切って
//配列data[]に整数化して入れておく
int data[]=int(split(stringData,','));
//配列data[]内のデータが３つなら、
if(data.length==3){
//三つの値をそれぞれマッピングして代入
r=int(map(data[0],0,4095,0,255));
g=int(map(data[1],0,4095,0,255));
b=int(map(data[2],0,4095,0,255));
//合図用データ送信
port.write(65);
}
}
}
//マウスが押されたら通信開始
void mousePressed(){
//開始用データ送信
port.write(65);
}
Arduinoからは0~4095の範囲で値が送られてくるので、
fill(r,g,b)の各値に代入するため、
map()を使って0~255までの値（さらに
int()で括って整数に変換）に変換しています。
米本 和也
CQ出版
売り上げランキング: 21816
投稿
