Arduino-Processing シリアル通信２

【変更】以下はArduino1.0まで対応したプログラム内容です。

特にシリアル通信においては、Arduino2.0使用の際、バイト送信する場合、

Serial.print(value,BYTE);

のかわりに、

Serial.write(value);

を使用してください。

前回のシリアル通信では、ひとつの値をArduinoからProcessingへ一方的に送り続ける内容でした。今回は、Arduino側から三つの可変抵抗器を使って、三つの異なる値をProcessingへ送りたいと思います。

例えば、Processing上の３DモデルのX座標、Y座標、Z座標の値を送り、それぞれのツマミで三次元的に立体を動かすことができるプログラムになるということです。
Arduinoから３つの値を送るには、

Serial.write(x);
Serial.write(y);
Serial.write(z);

となります。
３つの値がXYZの順番で送られる場合、XYZ XYZ XYZ・・・と繰り返されますが、Processing側の読み取りを開始するタイミングがずれると、最初の幾つかの値をスキップしてしまい、YZX YZX YZX・・・、あるいはZXY ZXY ZXY・・・となってしまいます。このように、順番がずれないようにするためには通信上の工夫が必要となります。今回の方法では、３つの値を一方的に送るのではなく、受取確認をしながらお互いに通信します。以下にプログラムを書きます。

Arduino側のプログラム：

//x,y,zの３つの変数を用意し、初期値を０とする
int x=0;
int y=0;
int z=0;

void setup(){
  //シリアル通信開始
  Serial.begin(9600);
}

void loop(){
  //アナログ入力ピン0,1,2を
  //それぞれx,y,zに対応させる
  //値を４で割って最大値255にする
  x=analogRead(0)/4;
  y=analogRead(1)/4;
  z=analogRead(2)/4;

  //Processingから合図のデータが
  //一つ送られてきたらという条件
  if(Serial.available()>0){
    //x,y,zの順番で値を送る
    Serial.write(x);
    Serial.write(y);
    Serial.write(z);
    //先ほどのProcessingからの
    //合図のデータを読み込む
    Serial.read();
  }
}

Arduinoプログラム上のSerial.available()は、外部（この場合Processing）から１バイト分のデータが何個送られてきているかを数えてくれます。送られてくるデータは、Arduinoであれ、Processingであれ、それぞれのメモリ上（バッファ領域）に一旦貯められます。その後、Serial.read()によって、貯められているデータから順番にひとつずつ読み込む処理をします。もし、読み込む処理をしなければ、送られたデータは次々とバッファ領域に溜まり続けます（設定した限界をこえるとそれ以上貯めることはできなくなります）。if(Serial.available()>0){...}という条件は、データが１個以上貯まったら（０個より多い場合）、{...}内の処理をするという意味です。

このプログラムの場合の手順は以下のようになります。

（１）まず、Processingから合図用のデータが送られてくる。
（２）合図用のデータが、一旦Arduinoのバッファ領域に貯められる。
（３）Serial.available()で、現在何個データが貯まっているか数える。
（４）合図用のデータが１個以上あれば、（５）以下を実行する。
（５）Serial.write(x)で、新たなxの値を送信する。
（６）Serial.write(y)で、新たなyの値を送信する。
（７）Serial.write(z)で、新たなzの値を送信する。
（８）Serial.read()で、バッファ領域内の合図用のデータを読み込む。
（９）結果、バッファ領域が空になる（データの個数が０個になる）。
（１０）Processingからの合図用のデータを待つ。

その後は（１）に戻り、同様の処理を繰り返します。要するに、Processingからの合図のデータが毎回１個送られて、それを確認後、Arduinoはx、y、zの値を送り返すという手順を踏みます。

次にProcessing側のプログラムを書きます。Arduinoのプログラムで書いたように、Processingからは、合図用のデータを１個送る必要があります。そうすれば、Arduinoから３個のデータが送られてくるので、Processingのバッファ領域にデータが３個貯まったときに、読み込む処理をさせればいいということになります。今回はx、y、zの３個の値なので3Dの図形を動かすプログラムにします。

Processing側のプログラム：

//シリアルライブラリを取り込む
import processing.serial.*;
//シリアルのオブジェクトmyPortを用意
Serial myPort;

//x,y,zの３個の変数を用意
int x=0;
int y=0;
int z=0;

void setup(){
  //3D用の画面サイズとして設定
  size(255,255,P3D);
  //シリアルポートの設定（「A4001Kjl」は基盤により異なる）
  //Windowsの場合は、"COM5"などとなる（前回ブログを参照）
  myPort=new Serial(this,"/dev/tty.usbserial-A4001Kjl",9600);
  //3D図形の塗りは無し（ワイヤーフレーム描画）
  noFill();
}

void draw(){
  //背景色を白に設定
  background(255);
  //3Dの位置座標にx,y,z入れる
  translate(x,y,z);
  //一辺50のボックス（立方体）を描画
  box(50);
}

//シリアル通信処理
void serialEvent(Serial p){
  //Arduinoから送られてきたデータが
  //３個（２より多い）の場合
  if(myPort.available()>2){
    //x,y,zの順番でデータを読み込む
    x=myPort.read();
    y=myPort.read();
    z=myPort.read();
    //読み込み後、合図データ送信
    myPort.write(65);
  }
}

//マウスが押されたら通信開始とする
void mousePressed(){
  //念のためバッファ領域を空にする
  myPort.clear();
  //とりあえず65という合図用データを送る
  myPort.write(65);
}

以上が、Processing側のプログラムです。3Dの場合は、size()の括弧内に画面幅、高さ以外に「P3D」を書き足します。ワイヤーフレームで描画した方が、今回の場合分かりやすいと思うので、noFill()をつかって塗り面を無しにしました。
void draw(){...}内のtranslate()は、その後に描画される3D図形の座標値をいれます。translate()に含まれる値が変化することで、3D図形は移動します。box()は、3Dの直方体を描画します。box(50,100,80)というように３つ値を入れれば、幅、高さ、奥行きをそれぞれ定義できます。box(50)の場合は、各辺が50の立方体になります。
シリアル通信の部分は、まずmousePressed()でマウスを押したときに、myPort.clear()でProcessingのバッファ領域内に貯まっているデータをとりあえず空にします（初期化）。そして通信を開始するきっかけとなる合図のデータをmyPort.write(65)で送ります。６５という値を送っていますが、０〜２５５の値であれば何でも構いません。Arduino側は送られてくるデータの個数を数えるのであって、データの中身の値については、何でもいいことになります。つまり、合図用に何らかのデータを１個送ればいいということです。一旦合図用のデータがProcessingから送られれば、次にArduinoがそのデータを受取り、そして３個のデータを送り返してきます。void serialEvent(Serial p){...}内のif(myPort.available()>2){...}内では、Arduinoから送られて来たデータがProcessingのバッファ領域に３個貯まったら（２個より多くなったら）myPort.read()で３回読み込み、x,y,zの３個の変数にそれぞれ値を入れていき、それらのデータは、box()の3D座標になるtranslate()に代入され、box()が動きます。



もう一度、手順をはじめから書くと、

（１）Arduinoの電源がオンになり、Arduinoのプログラムが開始。
（２）Processingのプログラムを立ち上げる。
（３）Arduinoは、Processingからの合図用データを待つ。
（４）Processing側でマウスを押す（通信開始）。
（５）Processingのバッファ領域を一旦空にする（初期化）。
（６）Processingから合図用データが１個送られる。
　＊以下、Arduino上での処理
（７）Arduinoのバッファ領域に合図用データが一旦貯められる。
（８）Arduinoのバッファ領域内のデータの個数を数える。
（９）データの個数が１個以上のとき、以下の処理を実行。
（１０）Arduinoから、新たなxの値を送信する。
（１１）Arduinoから、新たなyの値を送信する。
（１２）Arduinoから、新たなzの値を送信する。
（１３）バッファ領域内の合図用のデータを読み込む。
（１４）読み込んだ結果、Arduinoのバッファ領域が空になる。
（１５）次の合図用データがバッファ領域に貯まるまで待機。
　＊以下、Processing上での処理
（１６）Processingのバッファ領域にデータが貯められる。
（１７）Processingのバッファ領域内のデータの個数を数える。
（１８）データの個数が３個になったら、以下の処理を実行。
（１９）xの値として１番目のデータを読み込む。
（２０）yの値として２番目のデータを読み込む。
（２１）zの値として３番目のデータを読み込む。
（２２）その結果、Processingのバッファ領域が空になる。
（２３）Processingから合図用データが１個送られる。
（２４）次の３個のデータがバッファ領域に貯まるまで待機。
　＊その後は（７）へ戻り処理を繰り返します。

Serial.available()やmyPort.available()を使うことで、バッファ領域内に貯められているデータの個数を数え、その個数をもとにデータを送受信するタイミングを制御することができます。これ以外にも、送られる複数のデータの先頭部分や最後の部分に「.」（ピリオド）などの特定のデータを付け加えて送ることで、読み込み開始地点や読み込み終了地点を知らせる方法もあります。
シリアル通信を使うことで、コンピュータの内側と外側の世界をつなぐことができます。今後も様々な表現に応じて「シリアル通信」の技術は、繰り返し登場してきます。今回一気に理解できなくても、徐々に使いこなしていくことで、身についていくと思います。


関連：
「Arduino-Processing　シリアル通信１」（一つの値を送る／非同期通信）
「Arduino-Processing　シリアル通信３」（大きな値を複数送る）
「Processing-Arduino　シリアル通信４」（ProcessingからArduinoを制御する）
「Arduino-Processing　シリアル通信５」（複数の値を文字列で送信する）
「Arduino-Processing　シリアル通信６」 （２台のArduinoとProcessingを通信させる）